DSPTOP SFLCTL 最上部見出しコントロール(PYTHON.400/QDSPSRC.DSPTOP)
最終更新:
2025-11-26
0001.00 A R SFCTL01 SFLCTL(SFREC01)
0002.00 A TEXT(' ＳＦＬコントロール *SCRBAR')
0003.00 A SFLSIZ(0013)
0004.00 A *DS3 SFLSIZ(0011)
0005.00 A SFLPAG(0012)
0006.00 A *DS3 SFLPAG(0010)
0007.00 A ROLLUP(14 ' 次頁 ')
0008.00 A ROLLDOWN(15 ' 前頁 ')
0009.00 A CA03
0010.00 A CF04(04 'ﾌﾟﾛﾝﾌﾟﾄ')
0011.00 A 21 CA11
0012.00 A CA12
0013.00 A CA13
0014.00 A CA23
0015.00 A SETOF(99)
0016.00 A BLINK
0017.00 A OVERLAY
0018.00 A 42 SFLDSP
0019.00 A 41 SFLDSPCTL
0020.00 A 43 SFLINZ
0021.00 A 46 SFLDLT
0022.00 A 44 SFLCLR
0023.00 A 45 SFLEND(*MORE)
0024.00 A SFLCSRRRN(&RELRCD)
0025.00 A 61 SFLMSGID(EDT0411 QPDA/QEDTMSG 61)
0026.00 A 62 SFLMSGID(EDT0410 QPDA/QEDTMSG 62)
0027.00 A 63 SFLMSGID(CPD6A6D QSYS/QCPFMSG 63)
0028.00 A 99 SFLMSGID(CPF9897 QSYS/QCPFMSG +
0029.00 A 99 &MSGDTA)
0030.00 A DSPREC 4S 0H SFLRCDNBR(CURSOR)
0031.00 A RELRCD 5S 0H TEXT('SFL レコードの RRN')
0032.00 A RCD 10A H
0033.00 A FLD 10A H
0034.00 A CSRP 4S 0H TEXT('SFL 表示レコード№ ')
0035.00 A MSGDTA 144A P
[解説]
これは一覧表形式や伝票型式のSFLコントロール・レコードに使われるテンプレートです。
0002.00 A TEXT(' ＳＦＬコントロール *SCRBAR')
-> *SCRVARは AutoWebのスクロール・バー/2.0の表示を示しています。
これによってAutoWebで表示したときにスクロール・バーで画面のスクロールが
可能になります。
0007.00 A ROLLUP(14 ' 次頁 ') 0008.00 A ROLLDOWN(15 ' 前頁 ') 0009.00 A CA03 0010.00 A CF04(04 'ﾌﾟﾛﾝﾌﾟﾄ') 0011.00 A 21 CA11 0012.00 A CA12 0013.00 A CA13 0014.00 A CA23
-> CF04 の記述はPythonにはありませんがプログラマーは *IN04を検知して
プロンプト画面の処理を追加することができます。
また CA03, CA11, CA12, CA13, CA23 は次のように予約されています。
CA03=終了
CA11=変更: 変更モードに切換えます。
CA12=前画面: 初期画面の表示に戻ります。
CA13=出力待ち行列: SpoolライターVer5.0が導入されている場合は
WRKSPLが表示されて自分が印刷出力したスプールが
表示されて印刷、表示、PDF変換, Excel変換が可能になりました。
CA23=削除: 削除モードに切り替えます。
なお CAxxで記述されている機能キー処理はプログラマーが CFxxを記述することによって
CFxxの処理が優先されて実行されます。
0018.00 A 42 SFLDSP 0019.00 A 41 SFLDSPCTL 0020.00 A 43 SFLINZ 0021.00 A 46 SFLDLT 0022.00 A 44 SFLCLR 0023.00 A 45 SFLEND(*MORE)
=>SFLコントロールのこれらの標識はAS400エンジンの中で検知されて処理されますので
絶対に変更しないでください。
0030.00 A DSPREC 4S 0H SFLRCDNBR(CURSOR)
0031.00 A RELRCD 5S 0H TEXT('SFL レコードの RRN')
0032.00 A RCD 10A H
0033.00 A FLD 10A H
0034.00 A CSRP 4S 0H TEXT('SFL 表示レコード№ ')
0035.00 A MSGDTA 144A P
=>これらの特殊フィールドもAS400エンジンの内部処理で使われていますので
絶対に名前や属性も変更しないでください。